ECHO off

ECHO clear screen
CLS

ECHO do config
SET WORKDRIVE=I:
SET WORKDIR=I:\
SET z=I:\myUnattended\bin\7z.exe
SET SOURCEISO=I:\EN_WINDOWS_XP_PROFESSIONAL_X64.ISO
SET TARGET=I:\XPCD
SET SP=H:\HP\Microsoft\WindowsServer2003.WindowsXP-KB914961-SP2-x64-ENU.exe
SET SP2TARGET=I:\XPSP2
REM ARCH = amd64 | i386
SET ARCH=amd64
SET OEMPATH=I:\myUnattended\winXP64\xw4400
SET TARGETISO=I:\xpcd64bit.iso
SET CDIMAGE=I:\CDIMAGE\CDIMAGE.EXE
SET CDIMAGEBOOT=I:\CDIMAGE\boot_64bit.img
SET CDIMAGELABEL=WXPVOL_EN

ECHO change to working dir
CD %WORKDIR%
%WORKDRIVE%

ECHO delete traget (start from scratch)
RMDIR /S /Q %TARGET%

ECHO extract ISO file to target
START /WAIT  %z% x -o%TARGET% %SOURCEISO%
RMDIR /S /Q %TARGET%\[BOOT]

ECHO slipstream SP to target
REM %SP% -s:%TARGET%
REM %SP% /integrate:%TARGET%

ECHO extract service pack
MKDIR %SP2TARGET%
START /WAIT %SP% -x:%SP2TARGET% /passive

ECHO copy 32bit update
COPY %SP2TARGET%\%ARCH%\update\update.exe %SP2TARGET%\%ARCH%\update\update.exe.bak
COPY /Y I:\myUnattended\bin\update.exe %SP2TARGET%\%ARCH%\update\update.exe

ECHO integrate sp2 with update
REM %SP% -s:%TARGET%
START /WAIT %SP2TARGET%\%ARCH%\update\update.exe /integrate:%TARGET% /passive

ECHO delete sp2 path
RMDIR /S /Q %SP2TARGET%

ECHO copy oem directory
REM with 7z
REM START /WAIT %z% a %OEMPATH%\oem.7z %OEMPATH%\$OEM$
REM START /WAIT %z% x -o%TARGET% %OEMPATH%\oem.7z
REM DEL /Q %OEMPATH%\oem.7z
XCOPY %OEMPATH% %TARGET% /E /I /Y /Q

ECHO PATCH TXTSETUP
REM TODO: only if exists
TYPE %OEMPATH%\TXTSETUP.sif >> %TARGET%\%ARCH%\TXTSETUP.SIF

ECHO copy Winnt.sif
REM TODO: only if exists
COPY /Y %OEMPATH%\Winnt.sif %TARGET%\%ARCH%\Winnt.sif

ECHO copy boot drivers
COPY /Y %OEMPATH%\$OEM$\$1\Install\TXTSETUP\* %TARGET%\%ARCH%

ECHO create ISO
START /WAIT %CDIMAGE% -l%CDIMAGELABEL% -h -j1 -b%CDIMAGEBOOT% -x -o -m %TARGET% %TARGETISO%

ECHO done...
PAUSE